⬅️  Back Next ➡️

When initially the results for TNBC in Wikidata were so sparse, we look at the same queries for glioblastoma:

Contents:

  1. Genes associated with Glioblastoma through gene variant annotations
  2. Gene list linked through pathways on glioblastoma
  3. Concatenated list of GBM genes
  4. Chemical compounds part of a pathway on glioblastoma
  5. All cell lines associated with glioblastoma


Genes associated with Glioblastoma through gene variant annotations

Unlike TNBC, the gene variant associations returns a more sizable list of genes:

#title: Genes associated with Glioblastoma through gene variant annotations 
SELECT DISTINCT ?gene ?geneLabel ?variant ?variantLabel  WHERE {
  VALUES ?predicator {p:P3354 p:P3355 p:P3356 p:P3357 p:P3358 p:P3359}
  VALUES ?predicatorValue {ps:P3354 ps:P3355 ps:P3356 ps:P3357 ps:P3358 ps:P3359} 
  ?variant ?predictor ?node ;
          wdt:P3433 ?gene .
  ?node ?predicatorValue ?therapy .
  ?node pq:P2175 wd:Q282142 .
  ?prop wikibase:claim ?predicator .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}


Contents ↑


Gene list linked through pathways on glioblastoma

Or similarly, a pathway can be used as the semantic starting point for related genes. Here we see https://www.wikipathways.org/index.php/Pathway:WP2261, “Glioblastoma signaling pathways (Homo sapiens)”, a pathway that already existed in WikiPathways:

which produces this gene list:

#title: Gene list linked through pathways on glioblastoma
#description: This query returns a list of genes linked through pathways on glioblastoma.
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX bd: <http://www.bigdata.com/rdf#>

SELECT DISTINCT ?gene ?geneLabel ?scholia WHERE {
    VALUES ?disease {wd:Q282142}    # with a main subject of glioblastoma
    ?pathway wdt:P2410 ?wpid ;      # pathways with a Wikipathways ID
            wdt:P921 ?disease ;
            wdt:P527 ?gene .        # which has various parts
    ?gene wdt:P31 wd:Q7187 .       # part is of part gene
  BIND(uri(CONCAT("https://scholia.toolforge.org/gene/",REPLACE(str(?gene), "http://www.wikidata.org/entity/", ""))) as ?scholia)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}


Contents ↑


Concatenated list of GBM genes

This list can also be shortened and entered into https://string-db.org to provide a network interaction visualization:

#title: Concatenated list of GBM genes
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>

SELECT (GROUP_CONCAT(?geneLabel; SEPARATOR=" ") as ?geneList) WHERE {
    VALUES ?disease {wd:Q282142} # with a main subject of glioblastoma
    ?pathway wdt:P2410 ?wpid ;      # pathways with a Wikipathways ID
            wdt:P921 ?disease ;
            wdt:P527 ?gene .      # which has various parts
    ?gene wdt:P31 wd:Q7187 .       # part is of part gene

    ?gene rdfs:label ?geneLabel.
    FILTER(LANG(?geneLabel) = "en")
}

STRING Network Interactions

The list of genes from above can be entered here to visualize the network interactions from https://string-db.org:



Contents ↑


Chemical compounds part of a pathway on glioblastoma

#title: Chemical compounds part of a pathway on glioblastoma
SELECT DISTINCT ?compound ?compoundLabel ?scholia WHERE {
    ?pathway wdt:P2410 ?wpid ;      # pathways with a Wikipathways ID
            wdt:P921 wd:Q7843332 ; # with a main subject of triple negative breast cancer
            wdt:P527 ?compound .      # which has various parts
    ?compound wdt:P279*/wdt:P31 wd:Q11173 .       # part is subclass of of chemical compound
  BIND(uri(CONCAT("https://scholia.toolforge.org/chemical/",REPLACE(str(?compound), "http://www.wikidata.org/entity/", ""))) as ?scholia)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}


Contents ↑


All cell lines associated with glioblastoma

#title: All cell lines associated with glioblastoma
SELECT ?disease ?diseaseLabel ?scholia_disease ?cellLines ?cellLinesLabel ?scholia_cellLine ?cellosaurusId WHERE {
  VALUES ?diseaseRoot {  wd:Q282142 }
  ?cellLines wdt:P3289 ?cellosaurusId ;
            wdt:P5166 ?disease .
  ?disease wdt:P279* ?diseaseRoot .
  BIND(uri(CONCAT("https://scholia.toolforge.org/disease/",REPLACE(str(?disease), "http://www.wikidata.org/entity/", ""))) as ?scholia_disease)
  BIND(uri(CONCAT("https://scholia.toolforge.org/topic/",REPLACE(str(?cellLines), "http://www.wikidata.org/entity/", ""))) as ?scholia_cellLine)

  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" } .
}


Contents ↑


⬅️  Back Next ➡️